ASP level generation autoplay

This demo repeatedly generates and autoplays levels for the dungeon crawler toy domain at the end of the the previous post, which was in turn adapted from Chapter 8 of our PCG textbook.

It uses clingo running in the browser via clingo-wasm to generate the levels. The level generation logic ensures that the level is solvable and obeys stylistic constraints (see the previous post for details). Some Javascript code then animates the shortest path through the level.

The source code to this page is all un-obfuscated; feel free to borrow or adapt anything you find useful.

Level size (n×n, n=10..50):

Initializing WebAssembly...

#const width=20.

param("width",width).

dim(1..width).

tile((X,Y)) :- dim(X), dim(Y).

adj((X1,Y1),(X2,Y2)) :-
  tile((X1,Y1)),
  tile((X2,Y2)),
  |X1-X2|+|Y1-Y2| == 1.

start((1,1)).
finish((width,width)).

% tiles have at most one named sprite
0 { sprite(T,wall); sprite(T,gem); sprite(T,altar) } 1 :- tile(T).

% there is exactly one altar and one gem in the whole level
:- #count { T : sprite(T,altar) } != 1.
:- #count { T : sprite(T,gem) } != 1.

% style: at least half of the map has wall sprites
:- #count { T : tile(T), sprite(T,wall) } < (width*width)/2.

% style: altars have no surrounding walls for two steps
:- sprite(T1,altar), adj(T1,T2), adj(T2,T3), sprite(T3,wall).

% style: altars have four adjacent tiles (not up against edge of map)
:- sprite(T1,altar), #count { T2 : adj(T1,T2) } != 4.

% style: every wall has at least two neighbouring walls (no isolated rocks and spurs)
:- sprite(T1,wall), #count { T2 : adj(T1,T2), sprite(T2,wall) } < 2.

% style: gems have at least three surrounding walls (they are stuck in a larger wall)
:- sprite(T1,gem), #count { T2 : adj(T1,T2), sprite(T2,wall) } < 3.

% states:
%  1 --> initial
%  2 --> after picking up gem
%  3 --> after putting gem in altar

% you start in state 1
touch(T,1) :- start(T).

% possible navigation paths
{ touch(T2,2):adj(T1,T2) } :- touch(T1,1), sprite(T1,gem).
{ touch(T2,3):adj(T1,T2) } :- touch(T1,2), sprite(T1,altar).
{ touch(T2,S):adj(T1,T2) } :- touch(T1,S).

% you can't touch a wall in any state
:- sprite(T,wall), touch(T,S).

% the finish tile must be touched in state 3
completed :- finish(T), touch(T,3).
:- not completed.